This might help if you have lots of users to process.

It steps through the user folders, if there is a forward file it extracts the destination address and queues up any existing CNM's for delivery to that, then moves them out of the way.

Adjust the paths to suit.

(no warrantee etc. :))

[quote]

@echo off
set queue=c:\mercury\queuetest
set store=c:\mercury\mailstore
set FROM=slave@mydomain.com

cd %store%
for /f %%D in ('dir /a:d /b') do (
    if exist %%D\FORWARD (
        mkdir %%D\done
        echo $$ %FROM%>> header.txt
        for /f "delims=<> tokens=2" %%T in ('findstr /B "Forward-To:" %%D\FORWARD') do echo T %%T>> header.txt
        echo.>> header.txt
        for %%a in (%%D\*.cnm) do (
            copy /A header.txt + %%a %queue%\%%~na.101
            move %%a %%D\done
        )
        del header.txt
    )
)

[/quote]

Hello I have a rather unique problem:

I am using Mercury to forward mail for my users from an OLD domain to a NEW domain. My users use a forward file in their user account directory 

During a period of misconfiguration (read, FUBAR) mail was delivered into the user directories.

What I need is to have that mail processed by Mercury and forwarded properly without an addition from line introduced into the mail message.

How can I have mercury process the mail that is already delivered without using a mail client?

Thanks for your help 

Is NEW domain hosted on Mercury too?

If so, just move the .cnm's to the new user folder.

 Otherwise, add glue headers to the top of each message and drop into the queue dir as a .101 file. See here - http://community.pmail.com/forums/thread/21011.aspx

Thank you for the quick reply,

No, the new domain is not on the same machine. I read the post you directed me to.

I believe this will work but sadly I have hundreds of messages perhaps even thousands.

I dont suppose you happen to know of a scripted way to add the glue headers. It would have to be taken from the message body itself since I dont want to add an addition from line. I can see this as an easy problem in linux but I am on a windows machine.

I suppose I will need to search for windows awk and sed tools. Thanks for your help. 

You should just be able to use the NEW address & OLD address for the headers (for each user, obviously).

That is just what the FORWARD file does.

They are only used for the 'SMTP envelope' addresses and do not alter the original msg or add another From: header.

edit: Also for msg's with multi recipients, you really don't want to be resending to all of them, and BCC mails won't have the needed address in them anyway.